Day 1: Calorie Counting

1. Part 1
2. Part 2
3. Seen around
4. Visualization🌸

First day of new year of advent of code, happy to be back here having fun with nim and nimib and blogging about it. The idea for this year is to try and make visualization with p5nim.

Another thing I will be doing is using batteries for importing common stdlib modules. This is a nice convenience module that was supposed to improve on pattern of doing include prelude but it was decided not to put it in stdlib and you can now install it with nimble.

import batteries

Part 1

Solving any puzzle you take a lot of micro decision. Often I like to separate parsing and processing, but in cases like today it is very convenient to do both at once:

var
  elfs: seq[seq[int]]
  elf: seq[int]
  maxCalories: int

for line in day.filename.lines:
  if len(line.strip) > 0:
    elf.add parseInt(line)
  else:
    elfs.add elf
    if sum(elf) > maxCalories:
      maxCalories = sum(elf)
    elf = @[]
# at the end I still need to add last elf
if len(elf) > 0:
  elfs.add elf
  # and maybe he is the one bringing most calories
  if sum(elf) > maxCalories:
    maxCalories = sum(elf)

echo maxCalories

73211

That's the right answer! You are one gold star closer to collecting enough star fruit.

Part 2

Easiest (not most performant) to get top three is to sort:

sort(elfs, ((elfA, elfB) => sum(elfA) - sum(elfB)), order=SortOrder.Descending)

echo sum elfs[0..2].mapIt(sum it)

213958

That's the right answer! You are one gold star closer to collecting enough star fruit.

Seen around

Section "seen around" is where I gather interesting stuff seen around about advent of code for today:

• daily solution megathread to post your solution (I did!). seen a couple of people doing it in Nim

• community fun event thread (I will have to participate with p5nim project)

• unofficial participant survey, do it and mention you are using Nim! (I did complete the survey)

• a nice visualization (apparently done in PyCairo)

• eric wastl aka r/topaz aka creator of adventofcode is worried about user agents and has some advice to give

• this year we will have lots of AI generated visualizations here is one and another (with demons)

• I did also post my visualization on the subreddit

• this year are back the most beatiful nim solutions, the ones by MichalMarsalek

• PMunch is streaming again this year! you can watch it here (starts around 3:40, I am listening to it now)

• someone is solving aoc with github copilot (the idea comes from a nice discord of data professionals emigrated from twitter, you can find the prompt in the #advent-of-code chat there invite)

• will Peter Norvig do advent of code this year? has not started committing yet, if he does it will appear in his pytudes repo

• Jari Komppa last year did a great series of gifs for solutions, he is going at it this year too

Visualization

Let's look at total food and number of elfs before visualizing.

echo sum elfs.mapIt(sum it)
echo len(elfs)

11936991
254

Here is a very simple visualization:

• plot a rectangle for every elf, with length proportional to the food
• every piece of food is colored with a color extracted from a palette
• list of palettes is taken from takawo
• I also wait a moment before starting and wait also at the end

const
  ratio = 100.0
  hElf = 2
  idxWait = 100
var idx = -20

proc showElf(x, y: float, food: seq[int], colors: seq[string]) =
  push()
  translate(x, y)
  for i, f in food:
    fill(colors[i mod colors.len])
    rect(0, 0, f / ratio, hElf)
    translate(f / ratio, 0)
  pop()

echo elfs
setup:
  createCanvas(800, hElf*len(elfs))
  #createCanvas(800, 800)
  background(colDark)
  frameRate(50)
  noStroke()
draw:
  if idx < elfs.len:
    if idx >= 0: # wait before starting
      showElf(0, hElf*idx, elfs[idx], palettes[idx mod len palettes])
    inc idx
  else:
    # wait a moment
    inc idx
    if idx > elfs.len + idxWait:
      background(colDark)
      idx = -60

for an older version of this visualization go here